/*
2-24-92 Tells you about the standard things about a room, whether the messages
  are set, etc.
C. Regis Wilson

$room:@stand*ards any none none
*/
set_task_perms(player);
bad = 0;
exit_msgs = {"description","leave_msg","oleave_msg","oarrive_msg"};
entrance_msgs = {"description","leave_msg","oleave_msg","oarrive_msg"};
dobj = $string_utils:match_object(dobjstr,player.location);
if (!valid(dobj) || !$object_utils:isa(dobj,$room))
  dobj = player.location;
endif
player:tell("Using room ",dobj.name,"(#",tonum(dobj),").");
if (!dobj.description)
  player:tell(dobj.name,"(#",tonum(dobj),") does not have a description.");
  bad = 1;
endif
for exit in (dobj.exits)
  out = "Exit "+exit.name+"(#"+tostr(tonum(exit))+")";
  if (! $object_utils:isa(exit,$exit))
    player:tell(out," does not have a valid destination.");
    bad = 1;
  endif
  for msg in (exit_msgs)
    if (!exit.(msg))
      player:tell(out," does not have the ",msg," set.");
      bad = 1;
    endif
  endfor
endfor
for entrance in (dobj.entrances)
  out = "Entrance "+entrance.name+"(#"+tostr(tonum(entrance))+")";
  if (! $object_utils:isa(entrance,$exit))
    player:tell(out," does not have a valid destination.");
    bad = 1;
  endif
  for msg in (entrance_msgs)
    if (!entrance.(msg))
      player:tell(out," does not have the ",msg," set.");
      bad = 1;
    endif
  endfor
endfor
if (! bad)
  player:tell("This room matches wizard specs.");
endif